*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMSL0402AU_H v.20220620.txt
*  Product Name      	: JMSL0402AU (PDFN3x3-8L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Jun20, 2022
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSL0402AU D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.0018
RS S 3 1E-009
RG G 2 1.3
CGS 3 G 2E-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 8E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 2.921910E-09 -1.489890E-10 3.173330E-12 5.816110E-13 -5.055700E-14 1.404120E-15 -1.296130E-17

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0    
+acm = 3                       VMAX = 1E9                    ETA = 1E-4   
+VTO = 1.54                    TOX = 8E-10                   NSUB = 1E22   
+KP = 800                      U0 = 200                      KAPPA = 0.1   
+GAMMA = 0.151947              PHI = 0.53                    THETA = 0.293494   
+BEX = -1.6                    TCV = 1E-4                    DELTA = 300    

.model DCGD D
+CJO = 8.8E-10                 VJ = 9                       M = 1.8  

.model DSUB D
+IS = 5E-12                    N = 1.015                     RS = 2E-3   
+BV = 45.5                     tlev = 0                      tlevc = 0   
+tref = 25                     eg = 1.201442                 keg = 1    
+gap1 = 3.999266E-4            gap2 = 1.108E3                xti = -1.8  
+cta = 0                       ctp = 0                       tcv = 0      
+tm1 = 0                       tm2 = 0                       tpb = 0   
+tphp = 0                      trs = 0                       ttt1 = 0  
+ttt2 = 0                      xtitun = 3   

.model DLIM D
+IS = 1E-4  
.ends JMSL0402AU

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************